Cr8-xyz/blender
1
0
Fork 0
Code Issues Pull Requests Actions 1 Packages Projects Releases Wiki Activity

Cycles OSL: refactoring and fixes

Browse Source 
* Moved kernel/osl/nodes to kernel/shaders
* Renamed standard attributes to use geom:, particle:, object: prefixes
* Update stdosl.h to properly reflect the closures we support
* Fix the wrong stdosl.h being used for building shaders
* Add geom:numpolyvertices, geom:trianglevertices, geom:polyvertices attributes
This commit is contained in:
Brecht Van Lommel
2012-11-03 14:32:13 +00:00
parent 6b098d7406
commit 615fe0295f
74 changed files with 124 additions and 151 deletions
Download Patch File Download Diff File Expand all files Collapse all files

81
intern/cycles/kernel/shaders/node_texture_coordinate.osl Normal file
View File

@@ -0,0 +1,81 @@
/*
* Copyright 2011, Blender Foundation.
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version 2
* of the License, or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software Foundation,
* Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
*/
#include "stdosl.h"
shader node_texture_coordinate(
normal NormalIn = N,
int is_background = 0,
int from_dupli = 0,
string bump_offset = "center",
output point Generated = point(0.0, 0.0, 0.0),
output point UV = point(0.0, 0.0, 0.0),
output point Object = point(0.0, 0.0, 0.0),
output point Camera = point(0.0, 0.0, 0.0),
output point Window = point(0.0, 0.0, 0.0),
output normal Normal = normal(0.0, 0.0, 0.0),
output point Reflection = point(0.0, 0.0, 0.0))
{
if (is_background) {
Generated = P;
UV = point(0.0, 0.0, 0.0);
Object = P;
point Pcam = transform("camera", "world", point(0, 0, 0));
Camera = transform("camera", P + Pcam);
Window = transform("NDC", P + Pcam);
Normal = NormalIn;
Reflection = I;
}
else {
if (from_dupli) {
getattribute("geom:dupli_generated", Generated);
getattribute("geom:dupli_uv", UV);
}
else {
getattribute("geom:generated", Generated);
getattribute("geom:uv", UV);
}
Object = transform("object", P);
Camera = transform("camera", P);
Window = transform("NDC", P);
Normal = transform("world", "object", NormalIn);
Reflection = reflect(I, NormalIn);
}
if (bump_offset == "dx") {
if (!from_dupli) {
Generated += Dx(Generated);
UV += Dx(UV);
}
Object += Dx(Object);
Camera += Dx(Camera);
Window += Dx(Window);
}
else if (bump_offset == "dy") {
if (!from_dupli) {
Generated += Dy(Generated);
UV += Dy(UV);
}
Object += Dy(Object);
Camera += Dy(Camera);
Window += Dy(Window);
}
}