0803119725
This includes much improved GPU rendering performance, viewport interactivity, new shadow catcher, revamped sampling settings, subsurface scattering anisotropy, new GPU volume sampling, improved PMJ sampling pattern, and more. Some features have also been removed or changed, breaking backwards compatibility. Including the removal of the OpenCL backend, for which alternatives are under development. Release notes and code docs: https://wiki.blender.org/wiki/Reference/Release_Notes/3.0/Cycles https://wiki.blender.org/wiki/Source/Render/Cycles Credits: * Sergey Sharybin * Brecht Van Lommel * Patrick Mours (OptiX backend) * Christophe Hery (subsurface scattering anisotropy) * William Leeson (PMJ sampling pattern) * Alaska (various fixes and tweaks) * Thomas Dinges (various fixes) For the full commit history, see the cycles-x branch. This squashes together all the changes since intermediate changes would often fail building or tests. Ref T87839, T87837, T87836 Fixes T90734, T89353, T80267, T80267, T77185, T69800
64 lines
2.0 KiB
CMake
64 lines
2.0 KiB
CMake
# - Find OptiX library
|
|
# Find the native OptiX includes and library
|
|
# This module defines
|
|
# OPTIX_INCLUDE_DIRS, where to find optix.h, Set when
|
|
# OPTIX_INCLUDE_DIR is found.
|
|
# OPTIX_ROOT_DIR, The base directory to search for OptiX.
|
|
# This can also be an environment variable.
|
|
# OPTIX_FOUND, If false, do not try to use OptiX.
|
|
|
|
#=============================================================================
|
|
# Copyright 2019 Blender Foundation.
|
|
#
|
|
# Distributed under the OSI-approved BSD 3-Clause License,
|
|
# see accompanying file BSD-3-Clause-license.txt for details.
|
|
#=============================================================================
|
|
|
|
# If OPTIX_ROOT_DIR was defined in the environment, use it.
|
|
IF(NOT OPTIX_ROOT_DIR AND NOT $ENV{OPTIX_ROOT_DIR} STREQUAL "")
|
|
SET(OPTIX_ROOT_DIR $ENV{OPTIX_ROOT_DIR})
|
|
ENDIF()
|
|
|
|
SET(_optix_SEARCH_DIRS
|
|
${OPTIX_ROOT_DIR}
|
|
"$ENV{PROGRAMDATA}/NVIDIA Corporation/OptiX SDK 7.0.0"
|
|
)
|
|
|
|
FIND_PATH(OPTIX_INCLUDE_DIR
|
|
NAMES
|
|
optix.h
|
|
HINTS
|
|
${_optix_SEARCH_DIRS}
|
|
PATH_SUFFIXES
|
|
include
|
|
)
|
|
|
|
IF(EXISTS "${OPTIX_INCLUDE_DIR}/optix.h")
|
|
FILE(STRINGS "${OPTIX_INCLUDE_DIR}/optix.h" _optix_version REGEX "^#define OPTIX_VERSION[ \t].*$")
|
|
STRING(REGEX MATCHALL "[0-9]+" _optix_version ${_optix_version})
|
|
|
|
MATH(EXPR _optix_version_major "${_optix_version} / 10000")
|
|
MATH(EXPR _optix_version_minor "(${_optix_version} % 10000) / 100")
|
|
MATH(EXPR _optix_version_patch "${_optix_version} % 100")
|
|
|
|
SET(OPTIX_VERSION "${_optix_version_major}.${_optix_version_minor}.${_optix_version_patch}")
|
|
ENDIF()
|
|
|
|
# handle the QUIETLY and REQUIRED arguments and set OPTIX_FOUND to TRUE if
|
|
# all listed variables are TRUE
|
|
INCLUDE(FindPackageHandleStandardArgs)
|
|
FIND_PACKAGE_HANDLE_STANDARD_ARGS(OptiX
|
|
REQUIRED_VARS OPTIX_INCLUDE_DIR
|
|
VERSION_VAR OPTIX_VERSION)
|
|
|
|
IF(OPTIX_FOUND)
|
|
SET(OPTIX_INCLUDE_DIRS ${OPTIX_INCLUDE_DIR})
|
|
ENDIF()
|
|
|
|
MARK_AS_ADVANCED(
|
|
OPTIX_INCLUDE_DIR
|
|
OPTIX_VERSION
|
|
)
|
|
|
|
UNSET(_optix_SEARCH_DIRS)
|